Questions on initiating constructor in DecentralizedStableCoin.sol, when it inherits Ownable contract.

[Glow-in-the-dark]

in DecentralisedStableCoin.sol, it inherits the 1) ERC20Burnable, which inherits the ERC20, and also the 2) Ownable contract.
However, the constructor of the DecentralizedStableCoin contract, only seems to initiate the constructor of the ERC20() , but not the Ownable() contract, which also have a constructor.

contract DecentralizedStableCoin is ERC20Burnable, Ownable {
    error DecentralizedStableCoin__MustBeMoreThanZero();
    error DecentralizedStableCoin__BurnAmountExceedsBalance();
    error DecentralizedStableCoin__NotZeroAddress();

    constructor () ERC20 ("DecentralizedStableCoin","DSC") {
    }

why is it not something like:

constructor () ERC20("DecentralizedStableCoin","DSC") Ownable(0xf39Fd6e51aad88F6F4ce6aB8827279cffFb92266){
    }

since under "Ownable.sol", there is a constructor, which is:

    constructor(address initialOwner) {
        _transferOwnership(initialOwner);
    }

My underrstanding is that the child contract inheriting the parent contract, will need to also include the parent's constructor.

Whis is the example:
https://github.com/Cyfrin/foundry-defi-stablecoin-f23/blob/main/src/DecentralizedStableCoin.sol

it inherits both parents, but only instantiate the ERC20 token, and does not include the Ownable's constructor.

[ChefAharoni]

EDIT: There was an update to OpenZeppelin's code two months ago that changed from the code I wrote below, to what you have. So yes, you should pass a parameter when initiating Ownable contract. Changes in the code can be seen in OpenZeppelin's repo, or specifically in this change's commit.

So when this course was filmed, Patrick used the version that had no parameters in the constructor, but there was an update since so now you must specify it :)

---

It's because the constructor in Ownable contract doesn't take any parameters.

As you can see in the following code snipper (I've only copied the relevant part), when Ownable is called, whatever is in the constructor will be automatically run - which is the _transferOwnership function, and it transfers it to the _msgSender, so no address is needed in the parameter.

abstract contract Ownable is Context {

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

On the other hand, in the ERC20 constructor, you can see that there's two parameters in the constructor, which must be entered when calling ERC20 contract:

contract ERC20 is Context, IERC20, IERC20Metadata {

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

[Glow-in-the-dark]

@ChefAharoni
Right, so now, in my in DecentralisedStableCoin.sol,

my code should then look like this?

import {Context} from "../utils/Context.sol";

contract DecentralizedStableCoin is ERC20Burnable, Ownable, Context {

constructor () ERC20("DecentralizedStableCoin","DSC") Ownable(_msgSender()){
    }
}

I'll have to import Context, Then put the _msgSender() inside ?

this should then work right?

[ChefAharoni]

Technically yes, but I'm not sure _msgSender will be the address of the contract deployer, even though it should.

Test to see if it works, and if not you can use msg.sender instead.

[Glow-in-the-dark]

@ChefAharoni

Not sure why when i inhert Context, it will have this error, and when i do not inhert Context, there will be no error.
Won't i need to inhert Context, in order to use the _msgSender() ? or as long as i import, and i do not need to inhert, i can still call the _msgSender() function, from the Context.sol

[ChefAharoni]

You don't need to import it at all because Ownable already imports it.

I just said I'm not sure it'll work with _msgSender because of contracts calling contracts, but for sure try using it without context.

[f3d0ss]

In my (and the course) "Ownable.sol" from the OpenZeppelin contracts there is this constructor:

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

Where are you getting that "Ownable.sol"?

[ChefAharoni]

In my (and the course) "Ownable.sol" from the OpenZeppelin contracts there is this constructor:
Where are you getting that "Ownable.sol"?

Looks like they updated the Ownable constructor two months ago, so now you must specify it.

[f3d0ss]

You are right, they changed the constructorin the master branch but in the last release (4.9.2) there is still the old constructor.
Now, I'm curious about how @Glow-in-the-dark installed those contracts.

[Glow-in-the-dark]

@f3d0ss Lol.. i just did this:
forge install openzeppelin/openzeppelin-contracts --no-commit

[f3d0ss]

Mmm maybe it's a different forge version than, because to me the v4.9.2 of the OpenZeppelin contracts get installed

[haard18]

Well i have tried this
constructor(address _owner) ERC20("DecentralizedStableCoin", "DSC") Ownable(_owner){}
Can anyone guide me if this would work and what change would i have to make in deploy scripts

[FrankezeCode]

I

Well i have tried this constructor(address _owner) ERC20("DecentralizedStableCoin", "DSC") Ownable(_owner){} Can anyone guide me if this would work and what change would i have to make in deploy scripts

It would work, but you would have to pass in an address as the owner during deployment.

But I would suggest you just used msg.sender