I am getting the Error Invalid type for argument in function call, Invalid implicit conversion from literal_string "" to bytes calldata requested in my performUpkeep function.

[PROWLERx15]

I am getting the following ERROR In my performUpkeep function Can you please help me solve it?

ERROR:

Invalid type for argument in function call. Invalid implicit conversion from literal_string "" to bytes calldata requested.
   --> src/Raffle.sol:144:45:
    |
144 |         (bool upkeepNeeded, ) = checkUpkeep("");

CODE:

function checkUpkeep(
        bytes calldata /* checkData */
    ) public view returns (bool upkeepNeeded, bytes memory /* performData */) {
        bool timeHasPassed = ((block.timestamp - s_LastTimeStamp) >=
            i_Interval);
        bool isOpen = s_RaffleState == RaffleState.OPEN;
        bool hasBalance = address(this).balance > 0;
        bool hasPlayers = s_Players.length > 0;

        upkeepNeeded = timeHasPassed && isOpen && hasBalance && hasPlayers;

        return (upkeepNeeded, "");
    }

    function performUpkeep(bytes calldata /* performData */) public {
        (bool upkeepNeeded, ) = checkUpkeep("");
        if (!upkeepNeeded) {
            revert Raffle__UpkeepNotNeeded(
                address(this).balance,
                s_Players.length,
                uint256(s_RaffleState)
            );
        }
        s_RaffleState = RaffleState.CALCULATING;

        VRFV2PlusClient.RandomWordsRequest memory request = VRFV2PlusClient
            .RandomWordsRequest({
                keyHash: i_keyHash,
                subId: i_subscriptionId,
                requestConfirmations: REQUEST_CONFIRMATIONS,
                callbackGasLimit: i_callbackGasLimit,
                numWords: NUM_WORDS,
                extraArgs: VRFV2PlusClient._argsToBytes(
                    //Set nativePayment to true to pay for VRF requests with Sepolia ETH instead of LINK
                    VRFV2PlusClient.ExtraArgsV1({nativePayment: false})
                )
            });

        uint256 requestId = s_vrfCoordinator.requestRandomWords(request);
    }
    ```
    

[EngrPips]

Hello @PROWLERx15, Please change the calldata location that you used for the performData argument in the performUpkeep function to memory and retry compiling.

[PROWLERx15]

Could you please elaborate and explain?

[EngrPips]

Have your checkUpKeep function below, then retry compiling.

function checkUpkeep(
        bytes memory /* checkData */
    ) public view returns (bool upkeepNeeded, bytes memory /* performData */) {
        bool timeHasPassed = ((block.timestamp - s_LastTimeStamp) >=
            i_Interval);
        bool isOpen = s_RaffleState == RaffleState.OPEN;
        bool hasBalance = address(this).balance > 0;
        bool hasPlayers = s_Players.length > 0;

        upkeepNeeded = timeHasPassed && isOpen && hasBalance && hasPlayers;

        return (upkeepNeeded, "");
    }