nextflow.config

// PAIRIS Pipeline Configuration

// Default parameters
params {
    // Project settings
    project_name = null
    peptide_fasta = null
    bcr_dir = null
    chain_dir = null

    // Analysis parameters
    window_sizes = null  // e.g., [15, 25] or null for full sequences
    num_seeds = 100
    num_diffusion_samples = 5  // AF3 num_diffusion_samples per seed

    // Folding backend selection
    folding_backend = 'alphafold3'  // 'alphafold3' (default) or 'esmfold2'
    esmfold2_model = 'fast'         // ESMFold2 variant: 'fast' (no MSAs) or 'full' (uses MSAs)
    esmfold2_conda_env = 'esmfold2' // conda env activated for the ESMFold2 folding step
    esmfold2_hf_home = null         // optional HF_HOME (model cache) for ESMFold2
    esmfold2_num_loops = 3          // ESMFold2 num_loops
    esmfold2_num_sampling_steps = 50  // ESMFold2 num_sampling_steps

    // Workflow stages
    run_msa_generation = true
    run_structure_prediction = true
    run_rosetta_analysis = true

    // Output directories
    outdir = "results"
    af3_output_dir = null  // Must be set by user (shared/group storage recommended)

    // SLURM settings
    partition = "preempted"

    // Environment settings (override in params.yml if needed)
    af3_module = 'alphafold/3.0.1-23-g792e61e'
    conda_env = 'pairis'
    rosetta_conda_env = 'rosetta'
    grouping_partition = 'cpu'
    max_memory = 128.GB
    max_cpus = 32
    max_time = 24.h

    // ===== Local Execution Settings =====
    af3_sif = null                     // Path to alphafold.sif
    af3_model_dir = null               // Path to AF3 model params
    af3_db_dir = null                  // Path to AF3 public databases
    local_num_gpus = 4                 // Number of GPUs available
    local_max_parallel_folding = 4     // Max concurrent GPU jobs
    local_max_parallel_cpu = 8         // Max concurrent CPU-bound jobs
    local_venv = null                  // Path to general uv venv (input gen, collation, extract, grouping)

    // Resource configuration (can be overridden in params.yml or command line)
    // MSA generation resources
    msa_cpus = 2
    msa_memory = '16.GB'
    msa_time = '1.h'
    msa_partition = 'cpu'

    // Structure folding resources
    folding_cpus = 1
    folding_memory = '16.GB'
    folding_time = '40.m'
    folding_gpu = 1
    folding_partition = 'gpu'

    // Rosetta analysis resources
    rosetta_cpus = 4
    rosetta_memory = '16.GB'
    rosetta_time = '8.h'
    rosetta_partition = 'cpu'

    // Extraction resources
    extract_cpus = 2
    extract_memory = '16.GB'
    extract_time = '60.m'
    extract_partition = 'cpu'
}

// Load Nextflow version
manifest {
    name = 'PAIRIS'
    description = 'Peptide-Antibody Interaction Research & Inference Suite'
    author = 'Monica Dayao'
    version = '1.0.0'
    nextflowVersion = '>=24.10.0'
}

// Executor configuration
executor {
    name = 'slurm'
    queueSize = 500
    submitRateLimit = '10 sec'
}

// Process configuration
process {
    executor = 'slurm'
    queue = params.partition

    // Default resources
    cpus = 1
    memory = 4.GB
    time = 45.m

    // Load mamba and activate conda environment for all processes
    beforeScript = "module load mamba && mamba activate ${params.conda_env}"

    // Process-specific labels
    withLabel: complex_input {
        cpus = 1
        memory = '4.GB'
        time = '5.m'
        queue = params.msa_partition
        array = 10000
    }

    withLabel: msa_input {
        cpus = 1
        memory = '4.GB'
        time = '5.m'
        queue = params.msa_partition
        array = 10000
    }

    withLabel: af3_msa {
        cpus = params.msa_cpus
        memory = params.msa_memory
        time = params.msa_time
        queue = params.msa_partition
        array = 10000
    }

    withLabel: af3_folding {
        cpus = params.folding_cpus
        memory = params.folding_memory
        time = params.folding_time
        queue = params.folding_partition
        clusterOptions = "--gres=gpu:${params.folding_gpu}"
        array = 10000
    }

    withLabel: esmfold2_folding {
        cpus = params.folding_cpus
        memory = params.folding_memory
        time = params.folding_time
        queue = params.folding_partition
        clusterOptions = "--gres=gpu:${params.folding_gpu}"
        array = 10000
        // Activate the ESMFold2 env (not the default conda_env) and, if set,
        // point HF_HOME at the model cache.
        beforeScript = "module load mamba && mamba activate ${params.esmfold2_conda_env}" + (params.esmfold2_hf_home ? " && export HF_HOME=${params.esmfold2_hf_home}" : "")
    }

    withLabel: rosetta {
        cpus = params.rosetta_cpus
        memory = params.rosetta_memory
        time = params.rosetta_time
        queue = params.rosetta_partition
        array = 10000
        beforeScript = "module load mamba && mamba activate ${params.rosetta_conda_env}"
    }

    withLabel: extract {
        cpus = params.extract_cpus
        memory = params.extract_memory
        time = params.extract_time
        queue = params.extract_partition
    }

    withLabel: grouping {
        cpus = 1
        memory = 8.GB
        time = 2.h
        queue = params.grouping_partition
    }
}

profiles {
    slurm {
        // Explicit SLURM profile (same as current default)
        executor.name = 'slurm'
    }

    local {
        executor {
            name = 'local'
            cpus = params.max_cpus
            memory = params.max_memory
        }

        process {
            executor = 'local'
            queue = null
            clusterOptions = null

            beforeScript = params.local_venv ? "source ${params.local_venv}/bin/activate" : ""

            withLabel: af3_folding {
                maxForks = params.local_max_parallel_folding
                array = null
            }
            withLabel: esmfold2_folding {
                maxForks = params.local_max_parallel_folding
                array = null
                beforeScript = "module load mamba && mamba activate ${params.esmfold2_conda_env}" + (params.esmfold2_hf_home ? " && export HF_HOME=${params.esmfold2_hf_home}" : "")
            }
            withLabel: af3_msa {
                time = params.msa_time
                maxForks = params.local_max_parallel_folding
                array = null
            }
            withLabel: rosetta {
                maxForks = params.local_max_parallel_cpu
                array = null
                // Match the ESMFold2 step: activate the mamba Rosetta env rather
                // than a uv venv, so local runs use the same env as SLURM.
                beforeScript = "module load mamba && mamba activate ${params.rosetta_conda_env}"
            }
            withLabel: msa_input {
                maxForks = params.local_max_parallel_cpu
                array = null
            }
            withLabel: complex_input {
                maxForks = params.local_max_parallel_cpu
                array = null
            }
            withLabel: extract { maxForks = params.local_max_parallel_cpu }
            withLabel: grouping { maxForks = 1 }
        }
    }
}

// Execution reports
timeline {
    enabled = true
    file = "${params.outdir}/reports/timeline.html"
    overwrite = true
}

report {
    enabled = true
    file = "${params.outdir}/reports/report.html"
    overwrite = true
}

trace {
    enabled = true
    file = "${params.outdir}/reports/trace.txt"
    overwrite = true
}

// Cleanup options
cleanup = false  // Set to true to delete work directory after successful completion